Para ello utilizaremos el método noise de la clase BitmapData, que rellena una imagen con píxeles que representan ruido aleatorio. La sintaxis es:

public noise(randomSeed:Number, [low:Number], [high:Number], [channelOptions:Number], [grayScale:Boolean]) : Void

Donde:

• randomSeed es el valor de inicialización aleatorio que se va a utilizar.
• low es el valor más bajo que se va a generar para cada canal (de 0 a 255). El valor predeterminado es 0.
• high es el valor más alto que se va a generar para cada canal (de 0 a 255). El valor predeterminado es 255.
• channelOptions es un número que puede ser una combinación de cualquiera de los cuatro valores de canal: 1 (rojo), 2 (verde), 4 (azul) y 8(alfa). Puede utilizar el operador lógico OR | para combinar valores de canal. El valor predeterminado es (1 | 2 | 4).
• grayScale es un valor booleano. Si es true, se creará una imagen en escala de grises estableciendo todos los canales de color con el mismo valor. La selección del canal alfa no se ve afectada por el establecimiento de este parámetro como true. El valor predeterminado es false.

Ejemplo:

//importamos la clase BitmapData
import flash.display.BitmapData;
//Creamos un clip de pelicula
//que contendra la imagen
this.createEmptyMovieClip("contenedor_mc", this.getNextHighestDepth());
//cargamos la imagen
contenedor_mc.loadMovie("img01.jpg");
//creamos una instancia 'ruido'
//a partir de la clase BitmapData
var ruido:BitmapData = new BitmapData(Stage.width, Stage.height, true);
//asociamos el mapa de bits al clip 
this.attachBitmap(ruido, this.getNextHighestDepth());
//creamos un intervalo de refresco
setInterval(actRuido, 100);
function actRuido() {
  //asociamos valores a partir de la posicion del raton
  var valor1 = 30 * _xmouse / Stage.width;
  var valor2 = 200 * _ymouse / Stage.height;
  //aplicamos el ruido
  ruido.noise(Math.round(Math.random() * 100000), valor1, valor2, 8, true);
}